home *** CD-ROM | disk | FTP | other *** search
/ EnigmA Amiga Run 1995 November / EnigmA AMIGA RUN 02 (1995)(G.R. Edizioni)(IT)[!][issue 1995-11][Skylink CD].iso / earcd / ear / mcp105r.lha / MCP / Install_MCP < prev    next >
Text File  |  1995-07-22  |  21KB  |  1,028 lines
  1.  
  2. ;================================= ENGLISH ==================================
  3.  
  4. (set languages-default 1)
  5.  
  6. (set #bad-kick "You must be using Kickstart 2.04+ to install MCP")
  7.  
  8. (set #copy-mcp "Copying MCP...")
  9.  
  10. (set #copy-mcpicon "Copying MCP-Icon...")
  11.  
  12. (set #copy-mcpprefs "Copying MCP preferences editor...")
  13.  
  14. (set #copy-catalog "Copying preferences translation...")
  15.  
  16. (set #copy-democonfig "Copying Democonfiguration...")
  17.  
  18. (set #copy-pointer "Copying Demo 16 color pointer...")
  19.  
  20. (set #copy-gurudat "Copying Guru informations...")
  21.  
  22. (set #copy-doc "Copying Documentations...")
  23.  
  24. (set #copy-patchcontrol "Copying PatchControl...")
  25.  
  26. (set #copy-showpatches "Copying ShowPatches...")
  27.  
  28. (set #copy-fixjump "Copying FixJump...")
  29.  
  30. (set #copy-reqtools-library "Copying reqtools.library to Libs: ...")
  31.  
  32. (set #copy-_asl-library "Copying _asl.library to Libs: ...")
  33.  
  34. (set #copy-envarc-env "Copying ENV:MCP to ENVARC:MCP ...")
  35.  
  36. (set #install-select
  37.     (cat
  38.         "Please select the different parts of MCP that you"
  39.         " would like to install:"
  40.     )
  41. )
  42.  
  43. (set #install-select-help
  44.     (cat
  45.         "MCP: The Master Control Program...\n"
  46.         "\n"
  47.         "MCP-Icon: The icon from MCP... It's worth using this,"
  48.         " if MCP should be installed to C:.\n"
  49.         "\n"
  50.         "MCP Preferences: The MCP preferences editor.\n"
  51.         "\n"
  52.         "Translations for MCPPrefs: The MCP-Preferences Cata-\n"
  53.         "log-files.\n"
  54.         "\n"
  55.         "Demo Configuration: A demo-configuration for MCP.\n"
  56.         "16 Color Pointer: Some 16-Color mousepointers.\n"
  57.         "\n"
  58.         "Guru Infos: MCP.gurudat. Needed for MCPs NoGuru and\n"
  59.         "AlertHistory.\n"
  60.         "\n"
  61.         "Documentation: The documentations for all programs.\n"
  62.         "\n"
  63.         "PatchControl: A program for better systempatch hand-\n"
  64.         "ling. Needed for MCPPrefs USE and TEST.\n"
  65.         "\n"
  66.         "ShowPatches: A tool to show all systempatches, if Pa-"
  67.         "tchControl was started.\n"
  68.         "\n"
  69.         "FixJump: To solve all problems with jumping BootPics.\n"
  70.         "\n"
  71.         "reqtools.library: Needed for MCP.\n"
  72.         "\n"
  73.         "_asl.library: A new asl.library for more memory.\n"
  74.         " Needed for MCPs OneReq."
  75.     )
  76. )
  77.  
  78. (set #doc-select
  79.     (cat
  80.         "Please select your favourite Documentation that you would"
  81.         " like to install:"
  82.     )
  83. )
  84.  
  85. (set #doc-select-help
  86.     (cat
  87.         "Make sure that you must have an AmigaGuide® viewer to"
  88.         " enjoy the Guide documentation!"
  89.     )
  90. )
  91.  
  92. (set #languages-select "\nWhich languages should be installed?")
  93.  
  94. (set #languages-select-help
  95.     (cat
  96.         "Please select your favourite language that should be"
  97.         " copied to you Locale: directory?"
  98.     )
  99. )
  100.  
  101. (set #pointer-select "Which 16-Color pointer should be installed? ")
  102.  
  103. (set #pointer-select-help
  104.     (cat
  105.         "There are Some REALLY NICE pointers available please check:"
  106.         "\n\nDescription of the pointers:\n\n"
  107.         "Blue + Joshi.: Blue Pointer With A Gold Medal of Joshi\n"
  108.         "ColorMagic...: Really Nice Pointer with a cream-tone and a"
  109.         " zZz-Busy Pointer"
  110.     )
  111. )
  112.  
  113. (set #pointer1 "Blue + Joshi by fOX!")
  114. (set #pointer2 "Colormagic   by Fli7e")
  115.  
  116. (set #startup-mcp "Do you want to insert MCP into your S:Startup-Sequence ?")
  117.  
  118. (set #startup-mcp-help
  119.     (cat
  120.         "If you select 'Yes', MCP will be inserted to your Startup-"
  121.         "Sequence after your last assign of ENV: \n"
  122.         "So it's automaticly installed on each bootup!"
  123.     )
  124. )
  125.  
  126. (set #startup-patchcontrol
  127.     (cat
  128.         "Do you want to insert PatchControl into your"
  129.         " S:Startup-Sequence ?"
  130.     )
  131. )
  132.  
  133. (set #startup-patchcontrol-help
  134.     (cat
  135.         "If you select 'Yes', Patchcontrol will be inserted right"
  136.         " after the SetPatch in your Startup-Sequence."
  137.     )
  138. )
  139.  
  140. (set #item-mcp "MCP")
  141.  
  142. (set #item-mcpicon "MCP-Icon")
  143.  
  144. (set #item-mcpprefs "MCP Preferences")
  145.  
  146. (set #item-translations "Translations for MCPPrefs")
  147.  
  148. (set #item-democonfig "Demo Configuration")
  149.  
  150. (set #item-demopointer "16 Color Pointer")
  151.  
  152. (set #item-gurudat "Guru Infos")
  153.  
  154. (set #item-doc "Documentations")
  155.  
  156. (set #item-patchcontrol "PatchControl")
  157.  
  158. (set #item-showpatches "ShowPatches")
  159.  
  160. (set #item-fixjump "FixJump")
  161.  
  162. (set #item-reqtools-library "reqtools.library")
  163.  
  164. (set #item-asl-library "_asl.library")
  165.  
  166. (set #where-mcp "Where would you like to install MCP?")
  167.  
  168. (set #where-mcp-help
  169.     (cat
  170.         "This is the destination directory of MCP"
  171.     )
  172. )
  173.  
  174. (set #where-mcpprefs "Where would you like to install MCP Preferences editor?")
  175.  
  176. (set #where-mcpprefs-help
  177.     (cat
  178.         "This is the destination directory of MCP preferences editor!"
  179.         " Normaly ALL preferences editors are in SYS:Prefs !"
  180.     )
  181. )
  182.  
  183. (set #where-gurudat "Where would you like to install the Guru-Information?")
  184.  
  185. (set #where-gurudat-help 
  186.     (cat
  187.         "The guru information is a file called MCP.gurudat"
  188.         " and it's normally placed in your S: directory.\n"
  189.         "If you installed the democonfig you have to use S:."
  190.     )
  191. )
  192.  
  193. (set #where-doc "Where would you like to install the Documentations?")
  194.  
  195. (set #where-patchcontrol "Where would you like to install PatchControl?")
  196.  
  197. (set #where-patchcontrol-help
  198.     (cat
  199.         "PatchControl is normally placed in you C: directory!"
  200.     )
  201. )
  202.  
  203. (set #where-showpatches "Where would you like to install ShowPatches?")
  204.  
  205. (set #where-showpatches-help
  206.     (cat
  207.         "ShowPatches is normally placed in you C: directory!"
  208.     )
  209. )
  210.  
  211. (set #where-fixjump "Where would you like to install FixJump?")
  212.  
  213. (set #where-fixjump-help
  214.     (cat
  215.         "FixJump is normally placed in you C: directory!"
  216.     )
  217. )
  218.  
  219. (set #run-conv "Please Wait... Converting In Progress")
  220.  
  221. (set #conv-ap "Do you want to convert AssignPrefs to MCP.config ?")
  222.  
  223. (set #conv-am "Do you want to convert AssignManager.prefs to MCP.config ?")
  224.  
  225. (set #conv-help
  226.     (cat
  227.         "If you convert your AssignPrefs / AssignManager, you"
  228.         " can drop this program if you select 'AssignPrefs = ON'"
  229.         " in the MCPPrefs program!"
  230.     )
  231. )
  232.  
  233. (set #install-exit
  234.     (cat
  235.         "Thank you for installing MCP ..."
  236.     )
  237. )
  238.  
  239. (set #install-start
  240.     (cat
  241.         "\nWelcome to MCP installation utility!\n\n"
  242.         ".######.    .######.\n"
  243.         "###  ###    ###  ###\n"
  244.         "     ###    ###  ###\n"
  245.         "  #####     ### .###\n"
  246.         "    .###    ### ####\n"
  247.         "### ####    ### ####\n"
  248.         "### #### ## ### ####\n"
  249.         "`######' ## `######'\n\n"
  250.         "Written and performed by fOX/aLiENDESiGN!\n"
  251.     )
  252. )
  253.  
  254. (set #run-prefs "Running MCPPrefs ! Configurate your MCP!")
  255.  
  256. (set #run-prefs-help
  257.     (cat
  258.         "If You Already run a older version of MCP you have to"
  259.         " save your config again!\n\n"
  260.         "New users have to configurate the whole MCP !"
  261.     )
  262. )
  263.  
  264.  
  265. ;===[ German Documentation ]=================================================
  266.  
  267. (if (= @language "deutsch")
  268.  (
  269. (set languages-default 2)
  270.  
  271. (set #bad-kick "Man benötigt Kickstart 2.04 oder höher, um MCP benutzen zu können!")
  272.  
  273. (set #copy-mcp "Kopiere MCP...")
  274.  
  275. (set #copy-mcpicon "Kopiere MCP-Icon...")
  276.  
  277. (set #copy-mcpprefs "Kopiere MCP Voreinsteller...")
  278.  
  279. (set #copy-catalog "Kopiere Voreinsteller-Übersetzungen...")
  280.  
  281. (set #copy-democonfig "Kopiere Demo Einstellung...")
  282.  
  283. (set #copy-pointer "Kopiere Demo 16 Farben Mauszeiger...")
  284.  
  285. (set #copy-gurudat "Kopiere Guru Informationen...")
  286.  
  287. (set #copy-doc "Kopiere Dokumentationen...")
  288.  
  289. (set #copy-patchcontrol "Kopiere PatchControl...")
  290.  
  291. (set #copy-showpatches "Kopiere ShowPatches...")
  292.  
  293. (set #copy-fixjump "Kopiere FixJump...")
  294.  
  295. (set #copy-reqtools-library "Kopiere reqtools.library ins Libs: ...")
  296.  
  297. (set #copy-_asl-library "Kopiere _asl.library ins Libs: ...")
  298.  
  299. (set #copy-envarc-env "Kopiere ENV:MCP ins ENVARC:MCP ...")
  300.  
  301. (set #install-select
  302.     (cat
  303.         "Bitte wähle die einzelnen Teile des MCP aus, die"
  304.         " Du installieren möchtest:"
  305.     )
  306. )
  307.  
  308. (set #install-select-help
  309.     (cat
  310.         "MCP: Das Master Control Program...\n"
  311.         "\n"
  312.         "MCP-Icon: Das Icon für MCP... Es ist nur nützlich wenn Du"
  313.         " MCP in das C: Verzeichnis installierst.\n"
  314.         "\n"
  315.         "MCP Preferences: Der MCP Voreinsteller (benötigt MUI).\n"
  316.         "\n"
  317.         "Übersetzungen für MCPPrefs: Die MCP-Voreinsteller Cata-\n"
  318.         "log-Dateien.\n"
  319.         "\n"
  320.         "Demo Einstellung: Eine Beispiel-Einstellung für MCP.\n"
  321.         "16 Farben Zeiger: Einige 16-Farben Mauszeiger.\n"
  322.         "\n"
  323.         "Guru Infos: MCP.gurudat. Wird von der MCP-NoGuru und\n"
  324.         "AlertHistory benutzt.\n"
  325.         "\n"
  326.         "Dokumentationen: Die Dokumentationen für alle Programme.\n"
  327.         "\n"
  328.         "PatchControl: Ist ein Programm das ein besseres SystemPatching\n"
  329.         "ermöglicht. Wird gebraucht, um bei MCPPrefs \"Benutzen\" und\n"
  330.         "\"Testen\" benutzen zu können\n"
  331.         "\n"
  332.         "ShowPatches: Zeigt die geänderten SystemFunktionen an.\n"
  333.         "\n"
  334.         "FixJump: Entfernt das Problem mit springenden BootBildern\n.\n"
  335.         "\n"
  336.         "reqtools.library: Wird vom MCP benötigt.\n"
  337.         "\n"
  338.         "_asl.library: Eine neue asl.library die weniger Speicher braucht.\n"
  339.         " Wird von der OneReq Funktion des MCP benutzt."
  340.     )
  341. )
  342.  
  343. (set #doc-select
  344.     (cat
  345.         "Bitte wähle die Dokumentationen aus, die Du installieren möchtest:"
  346.     )
  347. )
  348.  
  349. (set #doc-select-help
  350.     (cat
  351.         "Du brauchst einen AmigaGuide® Anzeiger, um die Guide Files anzuzeigen."
  352.     )
  353. )
  354.  
  355. (set #languages-select "\nWelche Sprachen sollen installiert werden?")
  356.  
  357. (set #languages-select-help
  358.     (cat
  359.         "Bitte suche die Sprache für MCPPrefs aus, die "
  360.         " in Dein Locale: Verzeichnis kopiert werden soll!"
  361.     )
  362. )
  363.  
  364. (set #pointer-select "Welcher 16-Farben Mauszeiger soll installiert werden?")
  365.  
  366. (set #pointer-select-help
  367.     (cat
  368.         "Erläuterung der MausZeiger:\n\n"
  369.         "Blue + Joshi.: Blauer Pfeil mit einer Gold Medaille von Joshi\n"
  370.         "ColorMagic...: Sehr schöner Cremefarbener Zeiger mit einem\n"
  371.         " zZz-Warte Zeiger"
  372.     )
  373. )
  374.  
  375. (set #pointer1 "Blue + Joshi von fOX!")
  376. (set #pointer2 "Colormagic   von Fli7e")
  377.  
  378. (set #startup-mcp "Möchtest Du MCP in Deine S:Startup-Sequence einfügen lassen?")
  379.  
  380. (set #startup-mcp-help
  381.     (cat
  382.         "Wenn Du 'Ja' auswählst, wird MCP in Deiner Startup-"
  383.         "Sequence nach dem letzten ENV: assign eingefügt.\n"
  384.         "Damit wird es automatisch beim Systemstart gestartet."
  385.     )
  386. )
  387.  
  388. (set #startup-patchcontrol
  389.     (cat
  390.         "Möchtest Du PatchControl in Deine S:Startup-Sequence einfügen lassen?"
  391.     )
  392. )
  393.  
  394. (set #startup-patchcontrol-help
  395.     (cat
  396.         "Wenn Du 'Ja' auswählst, wird PatchControl in Deiner Startup-Sequence nach dem SetPatch eingefügt."
  397.     )
  398. )
  399.  
  400. (set #item-mcpprefs "MCP Voreinsteller")
  401.  
  402. (set #item-translations "Übersetzungen für MCPPrefs")
  403.  
  404. (set #item-democonfig "Demo Einstellung")
  405.  
  406. (set #item-demopointer "16 Farben Mauspfeil")
  407.  
  408. (set #item-doc "Dokumentationen")
  409.  
  410. (set #where-mcp "Wohin möchtest Du MCP installieren?")
  411.  
  412. (set #where-mcp-help
  413.     (cat
  414.         "Dies ist das Zielverzeichnis von MCP."
  415.     )
  416. )
  417.  
  418. (set #where-mcpprefs "Wohin möchtest Du den MCP Voreinsteller installieren?")
  419.  
  420. (set #where-mcpprefs-help
  421.     (cat
  422.         "Dies ist das Zielverzeichnis vom MCP Voreinsteller!"
  423.         "Normalerweise sind alle Voreinstellungsprogramme im SYS:Prefs !"
  424.     )
  425. )
  426.  
  427. (set #where-gurudat "Wohin möchtest Du die Guru-Informationen installieren?")
  428.  
  429. (set #where-gurudat-help 
  430.     (cat
  431.         "Die Guru-Information heißt 'MCP.gurudat' und wird"
  432.         " normalerweise ins S: Verzeichnis installiert.\n"
  433.         "Wenn Du die Demo Einstellung installiert hast, wähle"
  434.         " das S: Verzeichnis"
  435.     )
  436. )
  437.  
  438. (set #where-doc "Wohin möchtest Du die Dokumentationen installieren?")
  439.  
  440. (set #where-patchcontrol "Wohin möchtest Du PatchControl installieren?")
  441.  
  442. (set #where-patchcontrol-help
  443.     (cat
  444.         "PatchControl wird normalerweise ins C: Verzeichnis"
  445.         " installiert!"
  446.     )
  447. )
  448.  
  449. (set #where-showpatches "Wohin möchtest Du ShowPatches installieren?")
  450.  
  451. (set #where-showpatches-help
  452.     (cat
  453.         "ShowPatches wird normalerweise ins C: Verzeichnis"
  454.         " installiert!"
  455.     )
  456. )
  457.  
  458. (set #where-fixjump "Wohin möchtest Du FixJump installieren?")
  459.  
  460. (set #where-fixjump-help
  461.     (cat
  462.         "FixJump wird normalerweise ins C: Verzeichnis"
  463.         " installiert!"
  464.     )
  465. )
  466.  
  467. (set #run-conv "Bitte warten... Konvertierung läuft!")
  468.  
  469. (set #conv-ap "Möchtest Du Deine AssignPrefs zur MCP.config konvertieren?")
  470.  
  471. (set #conv-am "Möchtest Du Deine AssignManager.prefs zur MCP.config konvertieren?")
  472.  
  473. (set #conv-help
  474.     (cat
  475.         "Wenn Du AssignPrefs / AssignManager Konfigurationen"
  476.         " konvertiert hast, kannst Du diese entfernen."
  477.     )
  478. )
  479.  
  480. (set #install-exit
  481.     (cat
  482.         "Vielen Dank für die Installation von MCP ...\n\n"
  483.         "...Fortsetzung folgt..."
  484.     )
  485. )
  486.  
  487. (set #install-start
  488.     (cat
  489.         "\nWillkommen zur MCP Installation!\n\n"
  490.         ".######.    .######.\n"
  491.         "###  ###    ###  ###\n"
  492.         "     ###    ###  ###\n"
  493.         "  #####     ### .###\n"
  494.         "    .###    ### ####\n"
  495.         "### ####    ### ####\n"
  496.         "### #### ## ### ####\n"
  497.         "`######' ## `######'\n\n"
  498.         "Geschrieben von fOX/aLiENDESiGN!\n"
  499.     )
  500. )
  501.  
  502. (set #run-prefs "Starte MCPPrefs... Konfiguriere nun den MCP!")
  503.  
  504. (set #run-prefs-help
  505.     (cat
  506.         "Wenn Du bereits eine ältere Version von MCP laufen hast,"
  507.         " speichere Deine Einstellung unbedingt neu!\n\n"
  508.     )
  509. )
  510.  )
  511. )
  512.  
  513. ;============================== PROGRAM-START================================
  514.  
  515. (set @default-dest "")
  516.  
  517. ; Check Kickstart (>= v2.0) Version.
  518.  
  519. (if (< (/ (getversion) 65536) 37)
  520.     (abort #bad-kick)
  521. )
  522.  
  523. (message #install-start)
  524.  
  525. (set install-default 1927)
  526.  
  527. (if (exists "Locale:" (noreq))
  528.     (set install-default (BITOR install-default 8))
  529. )
  530.  
  531. (if (NOT (exists "ENVARC:MCP/MCP.Config" (noreq)))
  532.     (set install-default (BITOR install-default 16))
  533. )
  534.  
  535. (if (NOT (exists "ENVARC:MCP/MCPPointer.prefs" (noreq)))
  536.     (set install-default (BITOR install-default 32))
  537. )
  538.  
  539. (if (NOT (exists "Libs:reqtools.library" (noreq)))
  540.     (set install-default (BITOR install-default 2048))
  541. )
  542.  
  543. (if (NOT (exists "Libs:_asl.library" (noreq)))
  544.     (set install-default (BITOR install-default 4096))
  545. )
  546.  
  547. (welcome)
  548.  
  549. (set install-files
  550.     (askoptions
  551.         (prompt    #install-select)
  552.         (help    #install-select-help "\n\n" @askoptions-help)
  553.         (choices
  554.             #item-mcp
  555.             #item-mcpicon
  556.             #item-mcpprefs
  557.             #item-translations
  558.             #item-democonfig
  559.             #item-demopointer
  560.             #item-gurudat
  561.             #item-doc
  562.             #item-patchcontrol
  563.             #item-showpatches
  564.             #item-fixjump
  565.             #item-reqtools-library
  566.             #item-asl-library
  567.         )
  568.         (default install-default)
  569.     )
  570. )
  571.  
  572. (set startup-files 0)
  573.  
  574. (if (BITAND install-files 1)
  575.     (
  576.         (set mcp-dest
  577.             (askdir
  578.                 (prompt    #where-mcp)
  579.                 (help    #where-mcp-help "\n\n" @askdir-help)
  580.                 (default "C:")
  581.             )
  582.         )
  583.         (if (RUN "C/Search S:StartUp-Sequence #?MCP PATTERN QUIET")
  584.             (if    (askbool
  585.                     (prompt #startup-mcp)
  586.                     (help #startup-mcp-help "\n\n" @askbool_help)
  587.                     (default 1)
  588.                 )
  589.                 (set startup-files (BITOR startup-files 1))
  590.             )
  591.         )
  592.     )
  593. )
  594.  
  595. (if (BITAND install-files 4)
  596.     (set mcpprefs-dest
  597.         (askdir
  598.             (prompt    #where-mcpprefs)
  599.             (help    #where-mcpprefs-help "\n\n" @askdir-help)
  600.             (default "SYS:Prefs/")
  601.         )
  602.     )
  603. )
  604.  
  605. (if (BITAND install-files 256)
  606.     (
  607.         (set patchcontrol-dest
  608.             (askdir
  609.                 (prompt    #where-patchcontrol)
  610.                 (help    #where-patchcontrol-help "\n\n" @askdir-help)
  611.                 (default "C:")
  612.             )
  613.         )
  614.         (if (RUN "C/Search S:StartUp-Sequence #?patchcontrol PATTERN QUIET")
  615.             (if    (askbool
  616.                     (prompt #startup-patchcontrol)
  617.                     (help #startup-patchcontrol-help "\n\n" @askbool_help)
  618.                     (default 1)
  619.                 )
  620.                 (set startup-files (BITOR startup-files 2))
  621.             )
  622.         )
  623.     )
  624. )
  625.  
  626. (if (BITAND install-files 512)
  627.     (set showpatches-dest
  628.         (askdir
  629.             (prompt    #where-showpatches)
  630.             (help    #where-showpatches-help "\n\n" @askdir-help)
  631.             (default "C:")
  632.         )
  633.     )
  634. )
  635.  
  636. ;Set FixJump Destination
  637.  
  638. (if (BITAND install-files 1024)
  639.     (set fixjump-dest
  640.         (askdir
  641.             (prompt    #where-fixjump)
  642.             (help    #where-fixjump-help "\n\n" @askdir-help)
  643.             (default "C:")
  644.         )
  645.     )
  646. )
  647.  
  648. ;Set MCP.gurudat Destination
  649.  
  650. (if (BITAND install-files 64)
  651.     (set gurudat-dest
  652.         (askdir
  653.             (prompt    #where-gurudat)
  654.             (help    #where-gurudat-help "\n\n" @askdir-help)
  655.             (default "S:")
  656.         )
  657.     )
  658. )
  659.  
  660. ; Check + DefaultSet + Request Of Documentation(s)
  661.  
  662. (if (BITAND install-files 128)
  663.     (
  664.         (if (= @LANGUAGE "deutsch")
  665.             (set doc-default 146)
  666.             (set doc-default 73)
  667.         )
  668.         (set doc-files
  669.             (askoptions
  670.                 (prompt    #doc-select)
  671.                     (help    #doc-select-help "\n\n" @askoptions-help)
  672.                     (choices
  673.                         "MCP.......... English"
  674.                         "MCP.......... Deutsch"
  675.                         "MCP.......... Français"
  676.                         "PatchControl. English"
  677.                         "PatchControl. Deutsch"
  678.                         "PatchControl. Français"
  679.                         "FixJump...... English"
  680.                         "FixJump...... Deutsch"
  681.                         "FixJump...... Français"
  682.                     )
  683.                 (default doc-default)
  684.             )
  685.         )
  686.         (set doc-dest
  687.             (askdir
  688.                 (prompt    #where-doc)
  689.                 (help    @askdir-help)
  690.                 (default "SYS:")
  691.             )
  692.         )
  693.     )
  694. )
  695.  
  696. (if (AND (BITAND install-files 8) (= (exists "Locale:") 2))
  697.     (set    languages
  698.         (askoptions
  699.             (prompt    #languages-select)
  700.             (help    #languages-select-help "\n\n" @askoptions-help)
  701.             (choices
  702.                 "English"
  703.                 "Deutsch"
  704.                 "Français"
  705.                 "Suomi"
  706.             )
  707.             (default languages-default)
  708.         )
  709.     )
  710. )
  711.  
  712. (if (BITAND install-files 32)
  713.     (set pointer
  714.         (askchoice
  715.             (prompt #pointer-select)
  716.             (help    #pointer-select-help)
  717.             (choices
  718.                 #pointer1
  719.                 #pointer2
  720.             )
  721.             (default 0)
  722.         )
  723.     )
  724. )
  725.  
  726. ;========================== COPY STARTS HERE ===============================
  727.  
  728. ; Copy MCP + Install in Startup
  729.  
  730. (if (BITAND install-files 1)
  731.     (
  732.         (set prozess (database "cpu"))
  733.         (if (< "68010" prozess)
  734.             (set mcp-source "MCP020")
  735.             (set mcp-source "MCP")
  736.         )
  737.         (copyfiles
  738.             (prompt #copy-mcp)
  739.             (source mcp-source)
  740.             (newname "MCP")
  741.             (dest mcp-dest)
  742.             (files)
  743.         )
  744.         (if (BITAND startup-files 1)
  745.             (RUN ("C/InsertText \"#?Assign#?ENV:#?\" \"%s\" LAST" (tackon mcp-dest "MCP")))
  746.         )
  747.     )
  748. )
  749.  
  750. (complete 7)
  751.  
  752. ; Copy MCP-Icon
  753.  
  754. (if (AND (BITAND install-files 2) (BITAND install-files 1))
  755.     (copyfiles
  756.         (prompt #copy-mcp-icon)
  757.         (source "MCP.info")
  758.         (dest mcp-dest)
  759.         (infos)
  760.     )
  761. )
  762.  
  763. (complete 14)
  764.  
  765. ;Copy MCP Preferences
  766.  
  767. (if (BITAND install-files 4)
  768.     (copyfiles
  769.         (prompt #copy-mcpprefs)
  770.         (source "Prefs/MCPPrefs")
  771.         (dest mcpprefs-dest)
  772.         (infos)
  773.     )
  774. )
  775.  
  776. (complete 21)
  777.  
  778. ; Copy catalog files
  779.  
  780. (if (and (BITAND install-files 8) (= (exists "Locale:") 2))
  781.     (
  782.         (set n 0)
  783.         (while
  784.             (set language
  785.                 (select n
  786.                     "English"
  787.                     "Deutsch"
  788.                     "Français"
  789.                     "Suomi"
  790.                     ""
  791.                 )
  792.             )
  793.             (
  794.                 (if (IN languages n)
  795.                     (if (<> 0 n)   ; No catalog for english strings...
  796.                         (
  797.                             (set catalogs (tackon "Locale/Catalogs" language))
  798.                             (set destination (tackon "Locale:Catalogs" language))
  799.                             (makedir destination)
  800.                             (if (exists (tackon catalogs "MCPPrefs.catalog"))
  801.                                 (copylib
  802.                                     (prompt #copy-catalog)
  803.                                     (source (tackon catalogs "MCPPrefs.catalog"))
  804.                                     (dest destination)
  805.                                 )
  806.                             )
  807.                         )
  808.                     )
  809.                 )
  810.                 (set n (+ n 1))
  811.             )
  812.         )
  813.     )
  814. )
  815.  
  816. (complete 28)
  817.  
  818. ;Copy Demo Config + Rename Old One !
  819.  
  820. (if (BITAND install-files 16)
  821.     (
  822.         (if (exists "ENVARC:MCP")
  823.             (rename "ENVARC:MCP/MCP.config" "ENVARC:MCP/MCP.Config.old")
  824.         )
  825.         (copyfiles
  826.             (prompt #copy-democonfig)
  827.             (source "ENVARC/MCP/MCP.Config")
  828.             (dest "ENVARC:MCP")
  829.         )
  830.         (if (exists "ENVARC:AssignManager.prefs")
  831.             (if
  832.                 (askbool
  833.                     (prompt #conv-am)
  834.                     (help #conv-help "\n\n" @askbool_help)
  835.                     (default 1)
  836.                 )
  837.                 (RUN "C/ConvAM"
  838.                     (prompt #run-conv)
  839.                 )
  840.             )
  841.         )
  842.         (if (exists "ENVARC:AssignPrefs")
  843.             (if
  844.                 (askbool
  845.                     (prompt #conv-ap)
  846.                     (help #conv-help "\n\n" @askbool_help)
  847.                     (default 1)
  848.                 )
  849.                 (RUN "C/ConvAP"
  850.                     (prompt #run-conv)
  851.                 )
  852.             )
  853.         )
  854.     )
  855. )
  856.  
  857. (complete 35)
  858.  
  859. ;Install 16 Color Pointer + Rename old one
  860.  
  861. (if (BITAND install-files 32)
  862.     (
  863.         (set pointer-source
  864.             (select pointer
  865.                 "mcppointer01.prefs"
  866.                 "mcppointer02.prefs"
  867.             )
  868.         )
  869.         (if (Exists "ENVARC:MCP" )
  870.             (rename "ENVARC:MCP/mcppointer.prefs" "ENVARC:MCP/MCPPointer.prefs.old")
  871.         )
  872.         (set source-file (tackon "ENVARC/MCP" pointer-source))
  873.         (copyfiles
  874.             (prompt #copy-pointer)
  875.             (source source-file)
  876.             (dest "ENVARC:MCP")
  877.             (newname "MCPPointer.prefs")
  878.         )
  879.     )
  880. )
  881.  
  882. (complete 42)
  883.  
  884. (if (BITAND install-files 64)
  885.     (copyfiles
  886.         (prompt #copy-gurudat)
  887.         (source "S/MCP.gurudat")
  888.         (dest gurudat-dest)
  889.     )
  890. )
  891.  
  892. (complete 49)
  893.  
  894. (if (BITAND install-files 128)
  895.     (
  896.         (set n 0)
  897.         (while
  898.             (set doc
  899.                 (select n
  900.                     "docs/MCP_eng.guide"
  901.                     "docs/MCP_ger.guide"
  902.                     "docs/MCP_fr.guide"
  903.                     "docs/PatchControl_eng.doc"
  904.                     "docs/PatchControl_ger.doc"
  905.                     "docs/PatchControl_fr.doc"
  906.                     "docs/FixJump_eng.doc"
  907.                     "docs/FixJump_ger.doc"
  908.                     "docs/FixJump_fr.doc"
  909.                     ""
  910.                 )
  911.             )
  912.             (
  913.                 (if (IN doc-files n)
  914.                     (copyfiles
  915.                         (prompt #copy-doc)
  916.                         (source doc)
  917.                         (dest doc-dest)
  918.                     )
  919.                 )
  920.                 (set n (+ n 1))
  921.             )
  922.         )
  923.     )
  924. )
  925.  
  926. (complete 56)
  927.  
  928. ; Copy PatchControl + Install in Startup
  929.  
  930. (if (BITAND install-files 256)
  931.     (
  932.         (copyfiles
  933.             (prompt #copy-patchcontrol)
  934.             (source "Tools/PatchControl")
  935.             (dest patchcontrol-dest)
  936.             (files)
  937.         )
  938.         (if (BITAND startup-files 2)
  939.             (if (exists "C:ARQ")
  940.                 (RUN ("C/InsertText \"#?SetPatch#?\" \"%s\"" (tackon patchcontrol-dest "PatchControl ARQ")))
  941.                 (RUN ("C/InsertText \"#?SetPatch#?\" \"%s\"" (tackon patchcontrol-dest "PatchControl")))
  942.             )
  943.         )
  944.     )
  945. )
  946.  
  947. (complete 63)
  948.  
  949. ;Copy ShowPatches
  950.  
  951. (if (BITAND install-files 512)
  952.     (copyfiles
  953.         (prompt #copy-showpatches)
  954.         (source "Tools/ShowPatches")
  955.         (dest showpatches-dest)
  956.     )
  957. )
  958.  
  959. (complete 70)
  960.  
  961. ;Copy FixJump
  962.  
  963. (if (BITAND install-files 1024)
  964.     (copyfiles
  965.         (prompt #copy-fixjump)
  966.         (source "Tools/FixJump")
  967.         (dest fixjump-dest)
  968.     )
  969. )
  970.  
  971. (complete 77)
  972.  
  973. ;Copy reqtools.library to libs:
  974.  
  975. (if (BITAND install-files 2048)
  976.     (copylib
  977.         (prompt #copy-reqtools-library)
  978.         (source "Libs/reqtools.library")
  979.         (dest "Libs:")
  980.     )
  981. )
  982.  
  983. (complete 84)
  984.  
  985. ;Copy _asl.library to Libs:
  986.  
  987. (if (BITAND install-files 4096)
  988.     (copylib
  989.         (prompt #copy-_asl-library)
  990.         (source "Libs/_asl.library")
  991.         (dest "Libs:")
  992.     )
  993. )
  994.  
  995. (complete 91)
  996.  
  997. ;Copy ENVARC:MCP to ENV:MCP if MCP-Democonfig or Pointer is installed!
  998.  
  999. (if (OR (BITAND install-files 16) (BITAND install-files 32))
  1000.     (if (askbool
  1001.         (prompt #copy-envarc-env)
  1002.         (help @askbool_help)
  1003.         (default 1)
  1004.     )
  1005.             (copyfiles
  1006.                 (source "ENVARC:MCP")
  1007.                 (dest "ENV:MCP")
  1008.                 (all)
  1009.             )
  1010.     )
  1011. )
  1012.  
  1013. (complete 98)
  1014.  
  1015. ;Run MCPPrefs Before Exiting
  1016.  
  1017. (if (BITAND install-files 4)
  1018.     (RUN (tackon mcpprefs-dest "MCPPrefs")
  1019.         (prompt #run-prefs)
  1020.         (help #run-prefs-help)
  1021.         (confirm 3)
  1022.     )
  1023. )
  1024.  
  1025. (complete 100)
  1026.  
  1027. (EXIT #install-exit)
  1028.